#!/usr/bin/perl
#
# to prepare, create and burn iso images
#

my $VERSION = "2.8.1";

use strict;
use File::NCopy qw(copy);       
use Mkcd::Commandline qw(parseCommandLine usage);
use Mkcd::Tools qw(printTable getTracks du cpal checkcds cleanrpmsrate config);
use Mkcd::Group;
use Mkcd::Package qw(packageOutOfRpmsrate getLeaves getRPMsKeys);
use packdrake;
use RPM::Header;

#
# config structure
#
# $config{name} = name for the product
#
# $config{list} = list data
#   $config{list}[list number]{name} = list name
#                             {filelist} = ( file list location 1, file list location 2, ..., file list location n )
#
#   $config{list}[list number]{packages}[location i] = (RPMS location i, SRPMS location i) 
#
#   $config{list}[list number]{done}
#                             {empty}
#                             {auto}
#                             {cd}
#                             {sources}
#
#   $config{list}[list number]{disc} = { cd => { rep => { options }}  }
#
# $config{disc} = disc data
#   $config{disc}[disc number]{size} = size in bytes
#   $config{disc}[disc number]{serial} = serial number
#   $config{disc}[disc number]{name} = disc number irl
#   $config{disc}[disc number]{longname} = disc long name
#   $config{disc}[disc number]{fastgeneric} = [ generic data 1, generic data 2, ..., generic data n]
#
#   $config{disc}[disc number]{function}{list}[function number] = (function name, { data })
#
#   $config{disc}[disc number]{function}{data}{dir}{repository identifier} = $config[2][cd number][1][function number]
#
#   $config{disc}[disc number]{function}{data}{'installation'} = $config[2][cd number][1][function number]  it should have only one installation by disc, anyway
#
#   $config{disc}[disc number]{function}{data}[2]{'advertising'} = $config[2][cd number][1][function number]
#
#   $config{disc}[disc number]{steps} = function to execute to build the disc
#
#
# $config other values:
#
#    discMax = higher real disc number 
#    configfile = config file use for this session 
#    lists
#    fast
#    nodeps
#    verbose
#    print
#    printscript
#    nolive
#    noiso
#    deps
#    nosrcfit
#    product
#    bugzilla
#    builddir
#    topdir
#    discsize
#    isodir
#    filetag
#    log
#    mkisoopt
#    tmp
#

#
# Availaible functions
#
#   see above @functions
#

# old -> new schema
#
# config structure
#
# $config[0][0] -> $config{name}
#
# $config[1] -> $config{list}
#   $config[1][list number][0] ->  $config{list}[list number]{filelist}
#
#   $config[1][list number][1][location i] -> $config{list}[list number]{packages}[location i]
#
#   $config[1][list number][2] -> $config{list}[list number]{done}, $config{list}[list number]{empty} $config{list}[list number]{cd}$config{list}[list number]{auto}
#
#   $config[1][list number][3] -> $config{list}[list number]{disc}
#
# $config[2] -> $config{disc}
#   $config[2][cd number][0] -> $config{disc}[disc number]{size}, $config{disc}[disc number]{serial}, $config{disc}[disc number]{name}, $config{disc}[disc number]{longname}, $config{disc}[disc number]{fastgeneric} 
#
#   $config[2][cd number][1][function number] -> $config{disc}[disc number]{function}{list}[function number]
#
#   $config[2][cd number][2]{dir}{repository identifier} -> $config{disc}[disc number]{function}{data}{dir}{repository identifier}
#
#   $config[2][cd number][2]{'installation'} -> $config{disc}[disc number]{function}{data}{'installation'}
#
#   $config[2][cd number][2]{'advertising'} -> $config{disc}[disc number]{function}{data}[2]{'advertising'}
#
#   $config[2][cd number][3] -> $config{disc}[disc number]{steps}
#
#
# $config[3] -> $config{discMax}, $config{configfile}
#
my $topdir = `pwd`;
chop $topdir;
my %config = (
    lists => [],
    fast => 0,
    nodeps => 0,
    verbose => 0,
    print => 0,
    printscript => 0,
    nolive => 0,
    noiso => 0,
    deps => 0,
    nosrcfit => 0,
    product => 0,
    bugzilla => 0,
    builddir => 0,
    topdir => $topdir,
    discsize => 681000000,
    isodir => 0,
    filetag => 0,
    log => 0,
    mkisoopt => "-r -J -hide-rr-moved -nobak -cache-inodes",
    tmp => $ENV{TMPDIR} || "$topdir/tmp"
);

my @params;
my %FUNCTIONS;
$config{group} = new Mkcd::Group(\%config);
my $functions = $config{group}{disc}{functions}{functions};
my @params = ( 
    #    [ "one letter option", "long name option", "number of args (-X means ´at least X´)", "help text", "function to call", "log info"]
    [ "","mkcd", 0, "<options>","mkcd Mandrake Linux Disc maker", sub { 1 }, ""],
    [ "a", "auto", [
	["", "auto", -1, "<repository> <extra RPMS directory 1> <extra RPMS directory 2> ... <extra RPMS directory n>","Auto mode configuration", 
	sub { 	my ($tmp,@arg) = @_;
	    $tmp->[0] ||= {};
	    push @$tmp, @arg;
	    1
	},"Setting auto mode arguments"],
	["c", "cd", 1, "<number of discs>","Max number of discs", sub { my ($tmp, $cd) = @_; if ($cd =~ /\d+/) { $tmp->[0]{cd} = $cd } else { return 0 }; 1 },"Setting max number of discs"],
	["s", "sources", 0, "","Create SRPMS discs too", sub { my ($tmp, $cd) = @_; $tmp->[0]{sources} = 1 },"Setting max number of discs"],
	["", "noisolinux", 0, "","Do not use a isolinux boot", sub { my ($tmp, $cd) = @_; $tmp->[0]{noisolinux} = 1 },"Setting noisolinux option"]
], "[options] <repository> <extra RPMS directory 1> <extra RPMS directory 2> ... <extra RPMS directory n>", "Automated mode, build discs from a repository.", \&autoMode, "Auto mode"],
    [ "", "bugzilla", 0, "","Use bugzilla as information source.", sub { $config{bugzilla} = 1 }, "Using Bugzilla"],
    [ "b", "builddir", 1, "<build dir>", "Where live iso image are created (default current dir).",  sub { $config{builddir} = pop @_ }, "Setting the build directory"],
    [ "", "batch", 2, "<discs list> <batch file>", "batch mode to rebuilt discs from a previous session.",  \&batchMode, "Batch mode"],
    [ "c", "catto", 1, "<log file>", "Log file.", sub { $config{log} = pop @_; open LOG,">$config{log}" or die "unable to open $config{log}\n"}, "Log file"],
    [ "", "listrpmsrate", 1,"<rpmsrate file>", "List the package in the rpmsrate file", \&packageOutOfRpmsrate, "Listing rpmsrate file"],
    [ "d", "depslist-creation", 0 , "", "rebuild the desplist.ordered file before checking the list.", sub { $config{deps}=1 }, "Depslist creation switch"],
    [ "", "discsize", 1 , "<disc size in bytes>", "Select a custom disc size (default $config{discsize}).", sub { $config{discsize} = pop}, "Custom disc size selection"],
    [ "f", "fast", 0 , "", "fast mode.", sub { $config{fast} = 1}, "Fast mode"],
    [ "g", "getdeps", -2, "<depslist.ordered directory> <package 1> <package 2> ... <package n>","Generate the dependencies list of a list of packages.", sub { getdeps(shift,[@_])}, "Generating dependencies list of the packages"],
    [ "", "getleaves", 1, "<depslist file>", "Getting leaves from a depslist.ordered file",\&getLeaves,"Getting leaves from a depslist.ordered"],
# FIXME function help should take 0 or one argument, but this is not possible with this structure
    [ "h", "help", -1, "<path> <to> <the> <function>", "Display help, eg. mkcd -h installation fixed. Type mkcd -h config for configuration files options.", sub { my (@function) = @_; if (@function) { my $key = join '/', @function; usage($key,$FUNCTIONS{$key}) } else { usage("mkcd",\@params)} 1}, ""],
    [ "", "check", -1, "<dir 1> <dir 2> ... <dir n>", "Check the hdlists, depslist and RPMS coherency.", sub { checkcds(@_)}, "Checking the hdlists, depslist and RPMs coherency"],
    [ "i", "isodir", 1, "<iso dir>", "Where ISOs are built (default ./iso/product_name/).",  sub { $config{isodir} = pop @_ }, "Setting the iso directory"],
    [ "k", "checkcu", -1, "<dir 1> <dir 2> ... <dir n>", "Checking the compssUser.", sub { checkcompssUser([0,@_])}, "Checking the compssUser"],
    [ "l", "lists", 1 , "","lists of discs taken into account.", sub { $config{lists} = getTracks(pop @_) }, "Using given disc list"],
    [ "m", "make", 1, "<cds number>", "Build the discs.", \&make , "Building the discs"],
    [ "", "nodeps", 0, "", "Do not include automatically dependencies of packages", sub { $config{nodeps} = 1 }, "Setting nodeps flag"],
    [ "", "nolive", 0, "", "Do not create live image of the discs.", sub { $config{nolive} = 1}, "Setting nolive option"],
    [ "", "noiso", 0, "", "Do not create iso images of the discs.", sub { $config{noiso} = 1}, "Setting noiso option"],
    [ "", "nosrcfit", 0, "", "Do not stop if sources discs are full", sub { $config{nosrcfit} = 1}, "Setting nosrcfit option"],
    [ "", "oem", -1, "<root of disc 1> <root of disc 2> ... <root of disc n>", "Build a OEM installation CD based on the given disc", \&oem, "Building oem disc" ],
    [ "p", "printscript", 1, "<script file>", "Print the script that can be use to rebuild the discs", sub { $config{printscript} = shift}, "Printing script"],
    [ "", "printdiscsfiles", 1, "<file>", "Print the contains of each disc", sub { $config{print} = shift}, "Printing disc contains"],
    [ "", "pl", -1, "<hdlist 1> <hdlist 2> ... <hdlist n>", "Do a packdrake -l on the hdlists", sub { getRPMsKeys(1,@_) }, "Printing hdlist contents"],
    [ "s","spec", 1, "<config file>","Configuration file", sub { config(shift,\%config,$functions) } , "Loading configuration file"],
    [ "t", "topdir", 1, "<top dir>", "Where files are created (default current dir).",  sub { $config{topdir} = pop @_; $config{tmp} = $ENV{TMPDIR} || "$config{$topdir}/tmp" }, "Setting the top directory"],
    [ "", "update-rpmsrate", -2, "<rpmsrate> <rpms directory 1> <rpms directory 2> ... <rpms directory n>", "Add major to libraries in rpmsrate",  sub { cleanrpmsrate(shift,0,0,@_) }, "Adding major to libraries in rpmsrate"],
    [ "", "verbose", 0 , "", "Print more messages", sub { $config{verbose} = 1}, "Setting the verbose flag"],
    [ "v", "version", 0, "", "Print program version",  sub { print {$config{LOG}} "\nmkcd version $VERSION\n"; 1}, ""]
);

# FIXME this permit to have specific help
foreach (@params){
    $FUNCTIONS{"$_->[1]"} = [ $_ ]
}

$FUNCTIONS{mkcd} = \@params;
foreach my $k (keys %{$functions}){
    $FUNCTIONS{$k} = $functions->{$k};
    foreach (@{$functions->{$k}}){
	$FUNCTIONS{"$k/$_->[1]"} = ref $_->[2] ? $_->[2] : [ $_ ]
    }
    push @{$FUNCTIONS{"config"}} , $functions->{$k}->[0]
}

local *LOG;
open LOG,">&STDERR";	
$config{LOG} = *LOG;

my $todo = parseCommandLine("mkcd",\@ARGV,\@params);
@ARGV and usage("mkcd",\@params,10);
foreach my $t (@$todo){
    print LOG "mkcd: $t->[2]\n";
    &{$t->[0]}(@{$t->[1]}) or print LOG "ERROR: $t->[2]\n";
}

sub batchMode{
    my ($cds,$file) = @_;
    config($file,\%config,$functions);
    my ($discsFiles,$cd) = readBatchFile($file);
    my ($lists,$cds) = getDiscsList($cds);
    my @mkisos;
    my @size;
    makeDiscs(0,$lists,$cds,\@size,\@mkisos,$discsFiles);
    makeDiscs(1,$lists,$cds,\@size,\@mkisos,$discsFiles,$cd);
}

sub getDiscsList {
    my ($cds) = @_;
    my $cds = getTracks($cds);
    print LOG "getDiscList: discs @$cds\n";
    my %list;
    $cds = [grep { ref $config{disc}[$_] and do { $list{$_} = 2; push @{$config{lists}}, $_} or print LOG "WARNING: disc $_ not defined\n" and 0} @$cds];
    $config{lists} ||= $cds;
    $config{lists} = [grep { $list{$_} or ref $config{disc}[$_] and $list{$_} = 1 or print LOG "WARNING: disc $_ not defined\n" and 0} @{$config{lists}}];
    return (\%list,$cds)
}

sub autoMode{
    my ($opt,$repository, @rpms) = @_;
    $config{nolive} = 1;
    $config{nosrcfit} = 1;
    $config{deps} = 1;
    -d "$repository/Mandrake" or print "ERROR: $repository/Mandrake does not exist\n" and return 0;
    my $dir = "$repository/Mandrake";
    local *DIR; opendir DIR, $dir;
    my $size;
    foreach (readdir DIR){
	-d "$dir/$_" or next;
	/RPMS(\d*)$/ or next;
	print LOG "autoMode: adding $dir/$_\n";
	unshift @rpms, "$dir/$_"
    }
    my ($name,$tag);
    if (-f "$repository/VERSION"){
	local *A; open A, "$repository/VERSION";
	<A>;
	/^Mandrake Linux (.*) \d{8} \d{2}:\d{2}$/;
	($name,$tag) = split ' ', $1
    }
    $name ||= "Cooker";
    $config{name} = $name;
    foreach (keys %$opt) { $config{list}[1]{$_} = $opt->{$_} }
    $config{list}[1]{auto} = 1;
    foreach (keys %{$config{list}[1]}) { print LOG "autoMode: list options $_ -> $config{list}[1]{$_}\n"}
    foreach (@rpms){
	#	$size += du($_);
	push @{$config{list}[1]{packages}}, [$_ , @rpms]
    }
    #print LOG "Total RPMS $size\n";
    $config{disc}[1]{size} = $config{discsize};
    $config{disc}[1]{serial} = "${name}-disc1";
    $config{disc}[1]{name} = 1;
    $config{disc}[1]{longname} = "MandrakeLinux $name";
    my $idx = 1;
    my %idx;
    &{$functions->{dir}[0][5]}(1,$idx,"rpms","Mandrake/RPMS");
    $idx++;
    &{$functions->{generic}[0][5]}(1,$idx,"rpms",1);
    $idx++;
    $idx{installation} = $idx;
    &{$functions->{installation}[0][5]}(1,$idx,"1/rpms");
    &{$functions->{installation}[5][5]}(1,$idx,"$repository");
    &{$functions->{installation}[10][5]}(1,$idx,"$tag");
    $idx++;
    &{$functions->{boot}[0][5]}(1,$idx);
    if (-w "$repository/isolinux/isolinux.bin" && !$opt->{noisolinux}){
	&{$functions->{boot}[1][5]}(1,$idx,{ isolinux => 1 },"isolinux");
	&{$functions->{boot}[2][5]}(1,$idx,{ bootimg => 1 },"isolinux/isolinux.bin");
	&{$functions->{boot}[5][5]}(1,$idx,"$repository/isolinux");
	$idx++;
	&{$functions->{cp}[0][5]}(1,$idx,"$repository/images","images/");
    }else{
	&{$functions->{boot}[2][5]}(1,$idx,{ bootimg => 1, dir => "Boot"},"images/cdrom.img");
	&{$functions->{boot}[4][5]}(1,$idx,"$repository/images");
    }
    if ($opt->{sources}){
    	$config{nosrcfit} = 0;
	$idx++;
	&{$functions->{dir}[0][5]}(1,$idx,"srpms","Mandrake/SRPMS");
	$idx++;
    	&{$functions->{generic}[0][5]}(1,$idx,"srpms",1);
    	&{$functions->{generic}[1][5]}(1,$idx, { source => 1});
        &{$functions->{installation}[17][5]}(1,$idx{installation},"1/srpms");
    }else {
     	&{$functions->{installation}[6][5]}(1,$idx)
    }
    printTable(\%config);
    $config{group}->makeWithGroups({ 1 => 2 },[ 1 ]);
    1	
}

sub make {
    my ($cds) = @_;
    $config{group}->makeWithGroups(getDiscsList($cds));
    1
}		

sub oem {
    my (@cds) = @_;
}

#
# Changeloh
#
# 2002 03 15
#
# new sources handling