[ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Índice] | [ ? ] |
47.1 Introdução a draw | ||
47.2 Definições para draw |
[ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Índice] | [ ? ] |
draw
é uma uma nova interface entre o Maxima e o Gnuplot.
Existem três funções a serem usadas n nível do Maxima:
draw2d
, draw3d
e draw
.
[ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Índice] | [ ? ] |
Valor padrão: false
Se xrange
for false
, o intevalo para a coordenada x é
calculado automaticamente.
Caso o usuário deseje um intervalo específico para x, esse intervalo deve ser fornecido como uma
lista da forma definida pelo Maxima, como em xrange=[-2, 3]
.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(xrange = [-3,5], explicit(x^2,x,-1,1))$ |
Veja também yrange
e zrange
.
Valor padrão: false
Se yrange
for false
, the range for the y coordinate is
computed automatically.
Se o usuário sesejar um intervalo específico para y, esse intervalo deve ser fornecido como uma
lista da forma definida pelo Maxima, como em yrange=[-2, 3]
.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(yrange = [-2,3], explicit(x^2,x,-1,1), xrange = [-3,3])$ |
Veja também xrange
e zrange
.
Valor padrão: false
Se zrange
for false
, o intervalo para a coordenada z é
calculado automaticamente.
Se o usuário sesejar um intervalo específico para z, esse intervalo deve ser fornecido como uma
lista da forma definida pelo Maxima, como em zrange=[-2, 3]
.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw3d(yrange = [-3,3], zrange = [-2,5], explicit(x^2+y^2,x,-1,1,y,-1,1), xrange = [-3,3])$ |
Veja também yrange
e zrange
.
Valor padrão: false
Se logx
for true
, o eixo xserá desenhado em
escala logarítmica.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(explicit(log(x),x,0.01,5), logx = true)$ |
Veja também logy
e logz
.
Valor padrão: false
Se logy
for true
, o eixo yserá desenhado em
escala logarítmica.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(logy = true, explicit(exp(x),x,0,5))$ |
Veja também logx
e logz
.
Valor padrão: false
Se logz
for true
, o eixo zserá desenhado em
escala logarítmica.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw3d(logz = true, explicit(exp(u^2+v^2),u,-2,2,v,-2,2))$ |
Veja também logx
e logy
.
Valor padrão: screen
Seleciona o terminal a ser usado pelo Gnuplot; os valores possíveis são:
screen
(o valor padrão), png
, jpg
, eps
, e eps_color
.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplos:
(%i1) load(draw)$ (%i2) /* screen terminal (default) */ draw2d(explicit(x^2,x,-1,1))$ (%i3) /* png file */ draw2d(terminal = 'png, pic_width = 300, explicit(x^2,x,-1,1))$ (%i4) /* jpg file */ draw2d(terminal = 'jpg, pic_width = 300, pic_height = 300, explicit(x^2,x,-1,1))$ (%i5) /* eps file */ draw2d(file_name = "myfile", explicit(x^2,x,-1,1), terminal = 'eps)$ |
Veja também file_name
, pic_width
, e pic_height
.
Valor padrão: false
Se grid
for true
, uma malha será desenhada sobre o plano xy.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(grid = true, explicit(exp(u),u,-2,2))$ |
Valor padrão: ""
(a seqüência de caracteres vazia)
A opção title
armazena uma seqüência de caracteres do Maxima com o título principal de um fundo gráfico.
Por padrão, nenhum título é escrito.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(explicit(exp(u),u,-2,2), title = "Exponential function")$ |
Valor padrão: ""
(a seqüência de caracteres vazia)
A opção xlabel
armazena uma seqüência de caracteres do Maxima com o rótulo para o eixo x.
Por padrão, nenhum rótulo é escrito.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(xlabel = "Time", explicit(exp(u),u,-2,2), ylabel = "Population")$ |
Veja também ylabel
, e zlabel
.
Valor padrão: ""
(a seqüência de caracteres vazia)
A opção ylabel
armazena uma seqüência de caracteres do Maxima com o rótulo para o eixo y.
Por padrão, nenhum rótulo é escrito.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(xlabel = "Time", ylabel = "Population", explicit(exp(u),u,-2,2) )$ |
Veja também xlabel
, e zlabel
.
Valor padrão: ""
(a seqüência de caracteres vazia)
A opção zlabel
armazena uma seqüência de caracteres do Maxima com o rótulo para o eixo z.
Por padrão, nenhum rótulo é escrito.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw3d(zlabel = "Z variable", ylabel = "Y variable", explicit(sin(x^2+y^2),x,-2,2,y,-2,2), xlabel = "X variable" )$ |
Veja também xlabel
, e ylabel
.
Valor padrão: true
Se xtics
for true
, a marcação numérica será feitas sobre o eixo x.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) /* No tics in the x-axis */ draw2d(xtics = false, explicit(exp(u),u,-2,2))$ |
Veja também ytics
, e ztics
.
Valor padrão: true
Se ytics
for true
, a marcação numérica será feitas sobre o eixo y.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(ytics = false, explicit(exp(u),u,-2,2), xtics = false)$ |
Veja também xtics
, e ztics
.
Valor padrão: true
Se ztics
for true
, a marcação numérica será feitas sobre o eixo z.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) /* No tics in the z-axis */ draw3d(ztics = false, explicit(sin(x^2+y^2),x,-2,2,y,-2,2) )$ |
Veja também xtics
, e ytics
.
Valor padrão: 60
rot_vertical
é o ângulo (em graus) da rotação vertical (em torno
do eixo x) para escolher o ponto de visualização em fundos gráficos tridimensionais.
O ângulo é associado ao intervalo [0, 180].
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw3d(rot_vertical = 170, explicit(sin(x^2+y^2),x,-2,2,y,-2,2) )$ |
Veja também rot_horizontal
.
Valor padrão: 30
rot_horizontal
é o ângulo (em graus) da rotação horizontal (em torno
do eixo z) para escolher o ponto de visualização em fundos gráficos tridimensionais.
O ângulo é associado ao intervalo [0, 180].
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw3d(rot_vertical = 170, rot_horizontal = 360, explicit(sin(x^2+y^2),x,-2,2,y,-2,2) )$ |
Veja também rot_vertical
.
Valor padrão: ""
(a seqüência de caracteres vazia)
xy_file
é o nome do arquivo onde as coordenada serão armazenadas
após um clique com o botão do mouse e pressionar a tecla 'x'. Por padrão,
nenhuma coordenada é armazenada.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Valor padrão: ""
(a seqüência de caracteres vazia)
Usuários experientes de Gnuplot podem fazer uso dessa opção para ajuste fino do comportamento
do Gnuplot escolhendo opções para serem enviadas antes do comando plot
ou do
comando splot
.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
O terminal dumb não é suportado pelo pacote draw
,
mas é possível escolher o terminal dumb fazendo uso da opção user_preamble
,
(%i1) load(draw)$ (%i2) draw2d(explicit(exp(x)-1,x,-1,1), parametric(cos(u),sin(u),u,0,2*%pi), user_preamble="set terminal dumb")$ |
Valor padrão: "maxima_out"
Esse é o nome do arquivo onde os terminais png
, jpg
, eps
e eps_color
guardarão o gráfico.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(file_name = "myfile", explicit(x^2,x,-1,1), terminal = 'png)$ |
Veja também terminal
, pic_width
, e pic_height
.
Valor padrão: 640
Essa é a largura do arquivo de bitmap gerado pelos terminais png
e jpg
.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(terminal = 'png, pic_width = 300, pic_height = 300, explicit(x^2,x,-1,1))$ |
Veja também terminal
, file_name
, e pic_height
.
Valor padrão: 640
Essa é a altura do arquivo de bitmap gerado pelos terminais png
e jpg
.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(terminal = 'png, pic_width = 300, pic_height = 300, explicit(x^2,x,-1,1))$ |
Veja também terminal
, file_name
, e pic_width
.
Valor padrão: true
Se axis_bottom
for true
, o eixo inferior é mostrado em fundos gráficos bidimensionais.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(axis_bottom = false, explicit(x^3,x,-1,1))$ |
Veja também axis_left
, axis_top
, axis_right
, e axis_3d
.
Valor padrão: true
Se axis_left
for true
, o eixo da esquerda é mostrado em fundos gráficos bidimensionais.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(axis_left = false, explicit(x^3,x,-1,1))$ |
Veja também axis_bottom
, axis_top
, axis_right
, e axis_3d
.
Valor padrão: true
Se axis_top
for true
, o eixo superior é mostrado em fundos gráficos bidimensionais.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(axis_top = false, explicit(x^3,x,-1,1))$ |
Veja também axis_bottom
, axis_left
, axis_right
, e axis_3d
.
Valor padrão: true
Se axis_right
for true
, o eixo da direita é mostrado em fundos gráficos bidimensionais.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(axis_right = false, explicit(x^3,x,-1,1))$ |
Veja também axis_bottom
, axis_left
, axis_top
, e axis_3d
.
Valor padrão: true
Se axis_3d
for true
, os eixos x, y e z são mostrados em fundos gráficos tridimensionais.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw3d(axis_3d = false, explicit(sin(x^2+y^2),x,-2,2,y,-2,2) )$ |
Veja também axis_bottom
, axis_left
, axis_top
, e axis_right
para eixos em duas dimensões.
Valor padrão: 1
point_size
escolhe o tamanho para os pontos do gr“afico. Esse valor deve ser um
número não negativo.
Essa opção afeta os seguintes objetos gráficos:
gr2d
: points
.
gr3d
: points
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(points(makelist([random(20),random(50)],k,1,10)), point_size = 5, points(makelist(k,k,1,20),makelist(random(30),k,1,20)))$ |
Valor padrão: 1
point_type
é um índice (maior ou igual a -1) para especificar como os pontos são mostrados.
As cores dos pontos são controladas com essa opção.
Essa opção afeta os seguintes objetos gráficos:
gr2d
: points
, explicit
, implicit
, parametric
, e polar
.
gr3d
: points
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(xrange = [0,10], yrange = [0,10], point_size = 3, point_type = 1, points([[1,1],[5,1],[9,1]]), point_type = 2, points([[1,2],[5,2],[9,2]]), point_type = 3, points([[1,3],[5,3],[9,3]]), point_type = 4, points([[1,4],[5,4],[9,4]]), point_type = 5, points([[1,5],[5,5],[9,5]]), point_type = 6, points([[1,6],[5,6],[9,6]]), point_type = 7, points([[1,7],[5,7],[9,7]]), point_type = 8, points([[1,8],[5,8],[9,8]]), point_type = 9, points([[1,9],[5,9],[9,9]]) )$ (%i3) draw2d(function_style = 'dots, point_type = -1, explicit(x^2,x,-1,1), point_type = 7, explicit(x^4,x,-1,1))$ |
Valor padrão: false
Se points_joined
for true
, pontos são unidos por linhas retas.
Essa opção afeta os seguintes objetos gráficos:
gr2d
: points
.
gr3d
: points
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(xrange = [0,10], yrange = [0,4], point_size = 3, point_type = 1, line_type = 3, points([[1,1],[5,1],[9,1]]), points_joined = true, point_type = 3, line_type = 5, points([[1,2],[5,2],[9,2]]), point_type = 5, line_type = 8, line_width = 7, points([[1,3],[5,3],[9,3]]) )$ |
Valor padrão: 1
fill_type
é um índice (maior ou igual a -1) para especificar a cor para regiões a serem preenchidas.
Essa opção afeta os seguintes objetos gráficos:
gr2d
: polygon
, rectangle
, ellipse
, explicit
, e implicit
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(fill_type = 6, polygon([[3,2],[7,2],[5,5]]), fill_type = 2, function_style = filled, explicit(sin(x),x,0,10) )$ |
Valor padrão: false
Se transparent
for true
, regiões internas de poligonos são
preenchidas de acordo com fill_type
.
Essa opção afeta os seguintes objetos gráficos:
gr2d
: polygon
, rectangle
, e ellipse
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(polygon([[3,2],[7,2],[5,5]]), transparent = true, line_type = 3, polygon([[5,2],[9,2],[7,5]]) )$ |
Valor padrão: true
Se border
for true
, bordas de polígonos são colorizadas
de acordo com line_type
e line_width
.
Essa opção afeta os seguintes objetos gráficos:
gr2d
: polygon
, rectangle
, e ellipse
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(line_type = 3, line_width = 8, polygon([[3,2],[7,2],[5,5]]), border = false, fill_type = 6, polygon([[5,2],[9,2],[7,5]]) )$ |
Valor padrão: false
Se head_both
for true
, vetores são mostrados com seta dupla na ponta.
Se false
, somente uma seta é mostrada.
Essa opção somente é relevante para objetos do tipo vector
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(xrange = [0,8], yrange = [0,8], head_length = 0.7, vector([1,1],[6,0]), head_both = true, vector([1,7],[6,0]) )$ |
Veja também head_length
, head_angle
, e head_type
.
Valor padrão: 2
head_length
indica, em unidades do eixo x, o comprimento da ponta da seta do vetor.
Essa opção é relevante somente para objetos do tipo vector
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(xrange = [0,12], yrange = [0,8], vector([0,1],[5,5]), head_length = 1, vector([2,1],[5,5]), head_length = 0.5, vector([4,1],[5,5]), head_length = 0.25, vector([6,1],[5,5]))$ |
Veja também head_both
, head_angle
, e head_type
.
Valor padrão: 45
head_angle
indica o ângulo, em graus, entre a ponta da seta do vetor e
o segmento que forma o corpo do vetor.
Essa opção é relevante somente para objetos do tipo vector
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(xrange = [0,10], yrange = [0,9], head_length = 0.7, head_angle = 10, vector([1,1],[0,6]), head_angle = 20, vector([2,1],[0,6]), head_angle = 30, vector([3,1],[0,6]), head_angle = 40, vector([4,1],[0,6]), head_angle = 60, vector([5,1],[0,6]), head_angle = 90, vector([6,1],[0,6]), head_angle = 120, vector([7,1],[0,6]), head_angle = 160, vector([8,1],[0,6]), head_angle = 180, vector([9,1],[0,6]) )$ |
Veja também head_both
, head_length
, e head_type
.
Valor padrão: filled
head_type
é usada para especificar como a ponta é mostrada. Valores
possíveis são: filled
(ponta fechada e preenchida), empty
(ponta fechada mas não preenchida), e nofilled
(ponta aberta).
Essa opção é relevante somente para objetos do tipo vector
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(xrange = [0,12], yrange = [0,10], head_length = 1, vector([0,1],[5,5]), /* default type */ head_type = 'empty, vector([3,1],[5,5]), head_type = 'nofilled, vector([6,1],[5,5]))$ |
Veja também head_both
, head_angle
, e head_length
.
Valor padrão: center
label_alignment
é usado para especificar onde escrever rótulos com
relação às coordenadas fornecidas. Valores possíveis são: center
,
left
, e right
.
Essa opção é relevante somente para objetos do tipo label
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(xrange = [0,10], yrange = [0,10], points_joined = true, points([[5,0],[5,10]]), label_color = 3, label("Centered alignment (default)",5,2), label_alignment = 'left, label("Left alignment",5,5), label_alignment = 'right, label("Right alignment",5,8))$ |
Veja também label_orientation
, e label_color
.
Valor padrão: horizontal
label_orientation
é usada para especificar a orientação dos rótulos.
Valores possíveis são: horizontal
, e vertical
.
Essa opção é relevante somente para objetos do tipo label
.
Exemplo:
Nesse exemplo, um ponto fictício é adicionado para firmar uma imagem.
o pacote draw
precisa sempre de dados para montar um fundo.
(%i1) load(draw)$ (%i2) draw2d(xrange = [0,10], yrange = [0,10], point_size = 0, points([[5,5]]), label("Horizontal orientation (default)",5,2), label_orientation = 'vertical, label("Vertical orientation",1,5))$ |
Veja também label_alignment
, e label_color
.
Valor padrão: 1
label_color
é um índice (maior ou igual a -1) para especificar a cor da fonte usada no rótulo.
Essa opção é relevante somente para objetos do tipo label
.
Exemplo:
Nesse exemplo, um ponto imaginário é adicionado para firmar uma imagem.
O pacote draw
precisa sempre de dados para desenharum fundo.
Essas cores podem mudar em diferentes terminais.
(%i1) load(draw)$ (%i2) draw2d(xrange = [0,10], yrange = [0,10], point_size = 0, points([[0,0]]), label_color = -1, label("Cor de rótulo -1",5,1), label_color = 1, label("Cor de rótulo 1 (default)",5,2), label_color = 2, label("Cor de rótulo 2",5,3), label_color = 3, label("Cor de rótulo 3",5,4), label_color = 4, label("Cor de rótulo 4",5,5), label_color = 5, label("Cor de rótulo 5",5,6), label_color = 6, label("Cor de rótulo 6",5,7), label_color = 7, label("Cor de rótulo 7",5,8), label_color = 8, label("Cor de rótulo 8",5,9) )$ |
Veja também label_alignment
, e label_orientation
.
Valor padrão: 1
line_width
é a lagura para linhas do gráfico.
Essa opção afeta os seguintes objetos gráficos:
gr2d
: points
, polygon
, rectangle
,
ellipse
, vector
, explicit
, implicit
,
parametric
e polar
.
gr3d
: points
e parametric
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(explicit(x^2,x,-1,1), /* default width */ line_width = 5, explicit(1 + x^2,x,-1,1), line_width = 10, explicit(2 + x^2,x,-1,1))$ |
Veja também line_type
.
Valor padrão: 1
line_type
é um índice (maior ou igual a -1) para especificar como linhas são mostradas.
A cor das linhas é controlada com essa opção.
Essa opção afeta os seguintes objetos gráficos:
gr2d
: points
, polygon
, rectangle
,
ellipse
, vector
, explicit
, implicit
,
parametric
e polar
.
gr3d
: points
, explicit
, parametric
e parametric_surface
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(explicit(x^2,x,-1,1), /* default type */ line_type = 5, explicit(1 + x^2,x,-1,1), line_type = 10, explicit(2 + x^2,x,-1,1))$ |
Veja também line_width
.
Valor padrão: 30
nticks
é o número de amostra de pontos usado pelas rotinas de montagem de gráfico.
Essa opção afeta os seguintes objetos gráficos:
gr2d
: ellipse
, explicit
, parametric
e polar
.
gr3d
: parametric
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(transparent = true, ellipse(0,0,4,2,0,180), nticks = 5, ellipse(0,0,4,2,180,180) )$ |
Valor padrão: 10
adapt_depth
é o número máximo de quebras usado pelas rotinas adaptativos de impressão.
Essa opção é relevante somente para funções 2d explicitas
.
Valor padrão: ""
(a seqüência de caracteres vazia)
key
é o nome de uma função na legenda. Se key
é uma
seqüência de caracteres vazia, nenhuma chave é atribuída à função.
Essa opção afeta os seguintes objetos gráficos:
gr2d
: points
, polygon
, rectangle
,
ellipse
, vector
, explicit
, implicit
,
parametric
, e polar
.
gr3d
: points
, explicit
, parametric
,
e parametric_surface
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(key = "Seno", explicit(sin(x),x,0,10), key = "Cosseno", line_type = 3, explicit(cos(x),x,0,10) )$ |
Valor padrão: lines
function_style
indica como funções são mostradas: com linhas (lines
) ou com pontos (dots
).
Essa opção afeta os seguintes objetos gráficos:
gr2d
: explicit
, implicit
,
parametric
, e polar
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(key = "Seno", explicit(sin(x),x,0,10), key = "Cosseno", function_style = 'dots, explicit(cos(x),x,0,10) )$ |
Valor padrão: 30
xu_grid
é o número de coordenadas da primeira variável
(x
na forma explícita e o número de coordenadas de u
em superfícies tridimensionais na forma paramétrica) para
contruir a grade dos pontos de amostra.
Essa opção afeta os seguintes objetos gráficos:
gr3d
: explicit
e parametric_surface
.
Exemplo:
(%i1) load(draw)$ (%i2) draw3d(xu_grid = 10, yv_grid = 50, explicit(x^2+y^2,x,-3,3,y,-3,3) )$ |
Veja também yv_grid
.
Valor padrão: 30
yv_grid
é o número de coordenadas da segunda variável
(y
na forma explícita e o número de coordenadas de v
em superfícies tridimensionais na forma paramétrica) para
construir a grade dos pontos de amostra.
Essa opção afeta os seguintes objetos gráficos:
gr3d
: explicit
e parametric_surface
.
Exemplo:
(%i1) load(draw)$ (%i2) draw3d(xu_grid = 10, yv_grid = 50, explicit(x^2+y^2,x,-3,3,y,-3,3) )$ |
Veja também xu_grid
.
Valor padrão: false
Se surface_hide
for true
, partes escondidas não são mostradas no gráfico em superfícies tridimensioais.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw(columns=2, gr3d(explicit(exp(sin(x)+cos(x^2)),x,-3,3,y,-3,3)), gr3d(surface_hide = true, explicit(exp(sin(x)+cos(x^2)),x,-3,3,y,-3,3)) )$ |
Valor padrão: none
Option contour
torna o usuário capaz de selecionar onde imprimir linhas de contorno.
Valores possíveis são:
none
:
nenhuma linha de contorno é mostrada.
base
:
linhas de contorno são projetadas no plano xy.
surface
:
linhas de contorno são mostradas sobre a superfície.
both
:
duas linhas de contorno são mostradas: no plano xy e sobre a superfície.
map
:
linhas de contorno são projetadas sobre o plano xy, e o ponto de boservação é
escolhido na vertical.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw3d(explicit(20*exp(-x^2-y^2)-10,x,0,2,y,-3,3), contour_levels = 15, contour = both, surface_hide = true) $ |
Valor padrão: 5
contour_levels
é o número de níveis em gráficos de contorno.
Uma vez que essa é uma opção gráfica global, sua posição na descrição do fundo não é importante.
Exemplo:
(%i1) load(draw)$ (%i2) draw3d(explicit(20*exp(-x^2-y^2)-10,x,0,2,y,-3,3), contour_levels = 15, contour = both, surface_hide = true) $ |
Valor padrão: 1
columns
é o número de colunas em gráficos multiplos.
Note que essa opção deve ser escrita fora de objetos gr2d
e de objetos gr3d
.
Exemplo:
(%i1) load(draw)$ (%i2) scene1: gr2d(title="Elipse", nticks=30, parametric(2*cos(t),5*sin(t),t,0,2*%pi))$ (%i3) scene2: gr2d(title="Triângulo", polygon([4,5,7],[6,4,2]))$ (%i4) draw(scene1, scene2, columns = 2)$ |
Valor padrão: [50, 50]
ip_grid
escolhe a grade para a primeira amostragem em gráficos implícitos.
Essa opção é relevante somente para implicit
objects.
Valor padrão: [5, 5]
ip_grid_in
escolhe a grade para a segunda amostragem em gráficos implícitos.
Essa opção é relevante somente para implicit
objects.
A função gr2d
constrói um objeto descrevendo um fundo gráfico em duas dimensões. Arguments are
opções gráficas e objetos gráficos. Esse fundo gráfico é interpretado
seqüêncialmente: opções gráficas afetam aqueles objetos gráficos colocados
imediatamente à sua direita.
Para fazer uso dessa função escreva primeiramente load(draw)
.
Adiante encontra-se uma lista de objetos gráficos disponívies para fundos gráficos em duas dimensões:
points([[x1,y1], [x2,y2], [x3,y3],...])
ou points([x1,x2,x3,...], [y1,y2,y3,...])
:
posiciona os pontos [x1,y1]
, [x2,y2]
, [x2,y2]
, ... no gráfico.
Esse objeto é efetado pelas seguintes opções gráficas: point_size
,
point_type
, points_joined
, line_width
, key
e line_type
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(key = "Small points", points(makelist([random(20),random(50)],k,1,10)), point_type = 6, point_size = 3, points_joined = true, key = "Great points", points(makelist(k,k,1,20),makelist(random(30),k,1,20)))$ |
polygon([[x1,y1], [x2,y2], [x3,y3],...])
ou polygon([x1,x2,x3,...], [y1,y2,y3,...])
:
desenha um polígono com vértices [x1,y1]
, [x2,y2]
, [x2,y2]
, ... no plano.
Esse objeto é afetado pelas seguintes opçs gráficas: transparent
,
fill_type
, border
, line_width
, key
e line_type
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(line_type = 3, line_width = 8, polygon([[3,2],[7,2],[5,5]]), border = false, fill_type = 6, polygon([[5,2],[9,2],[7,5]]) )$ |
rectangle([x1,y1], [x2,y2])
:
desenha um retângulo partindo do vértice [x1,y1]
e terminando no vértice [x2,y2]
oposto ao primeiro.
Esse objeto é afetado pelas seguintes opções gráficas: transparent
,
fill_type
, border
, line_width
, key
e line_type
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(fill_type = 6, line_width = 6, line_type = 2, transparent = false, fill_type = 8, rectangle([-2,-2],[8,-1]), /* opposite vertices */ transparent = true, line_type = 5, line_width = 1, rectangle([9,4],[2,-1.5]), xrange = [-3,10], yrange = [-3,4.5] )$ |
ellipse(xc, yc, a, b, ang1, ang2)
:
desenha uma elipse com centro em [xc, yc]
com semi-eixo maior a
e
semi-eixo menor b
traçando um arco de elipse que se inicia no ângulo ang1
e que vai
até o ângulo ang2
.
semi axis a
e b
, respectively, from angle ang1
to angle
ang2
.
Esse objeto é afetado pelas seguintes opções gráficas: nticks
,
transparent
, fill_type
, border
, line_width
,
line_type
e key
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(transparent = false, fill_type = 8, line_type = 5, transparent = false, line_width = 5, ellipse(0,6,3,2,270,-270), /* center (x,y), a, b, start & end in degrees */ transparent = true, line_type = 7, line_width = 3, ellipse(2.5,6,2,3,30,-90), xrange = [-3,6], yrange = [2,9] )$ |
label(rótulo,x,y)
:
escreve o rótulo
no ponto [x,y]
.
Esse objeto é afetado pelas seguintes opções gráficas: label_alignment
,
label_orientation
e label_color
.
Exemplo:
Nesse exemplo, um ponto imaginário é adicionado para firmar a imagem.
O pacote draw
precisa sempre da dados para desenhar um fundo.
Essas cores podem mudar em diferentes terminais.
(%i1) load(draw)$ (%i2) draw2d(xrange = [0,10], yrange = [0,10], point_size = 0, points([[0,0]]), label_color = -1, label("Cor de rótulo -1",5,1), label_color = 1, label("Cor de rótulo 1 (default)",5,2), label_color = 2, label("Cor de rótulo 2",5,3), label_color = 3, label("Cor de rótulo 3",5,4), label_color = 4, label("Cor de rótulo 4",5,5), label_color = 5, label("Cor de rótulo 5",5,6), label_color = 6, label("Cor de rótulo 6",5,7), label_color = 7, label("Cor de rótulo 7",5,8), label_color = 8, label("Cor de rótulo 8",5,9) )$ |
vector([x,y], [dx,dy])
:
desenha um vetor de componentes ortogonais [dx,dy]
com orígem eno ponto [x,y]
.
Esse objeto é afetado pelas seguintes opções gráficas: head_both
,
head_length
, head_angle
, head_type
, line_width
,
line_type
e key
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(xrange = [0,12], yrange = [0,10], head_length = 1, vector([0,1],[5,5]), /* default type */ head_type = 'empty, vector([3,1],[5,5]), head_both = true, head_type = 'nofilled, vector([6,1],[5,5]))$ |
explicit(fcn,var,minval,maxval)
:
monta o gráfico da função explícita fcn
, com variável var
assumindo valores
de minval
a maxval
.
Esse objeto é afetado pelas seguintes opções gráficas: nticks
,
adapt_depth
, line_width
, line_type
, key
, point_type
,
function_style
e fill_type
.
Exemplo:
(%i1) load(draw)$ (%i2) draw3d(xu_grid = 10, yv_grid = 50, explicit(x^2+y^2,x,-3,3,y,-3,3) )$ |
implicit(fcn,x-var,x-minval,x-maxval,y-var,y-minval,y-maxval)
:
monta o gráfico da função implícita definida por fcn
, com variável x-var
assumindo
de x-minval
a x-maxval
, e variável y-var
assumindo valores
de y-minval
a y-maxval
.
Esse objeto é afetado pelas seguintes opções gráficas: ip_grid
,
ip_grid_in
, line_width
, line_type
, key
,
filled_function
e fill_type
, e fill_type
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(grid = true, line_type = -1, key = "y^2=x^3-2*x+1", implicit(y^2=x^3-2*x+1, x, -4,4, y, -4,4), line_type = 0, key = "x^3+y^3 = 3*x*y^2-x-1", implicit(x^3+y^3 = 3*x*y^2-x-1, x, -4,4, y, -4,4), title = "Two implicit functions" )$ |
polar(radius,ang,minang,maxang)
:
plots function radius(ang)
defined in polar coordinates, com a variável ang
assumindo valores de minang
a maxang
.
Esse objeto é afetado pelas seguintes opções gráficas: nticks
,
line_width
, line_type
, key
,
function_style
e point_type
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(user_preamble = "set grid polar", nticks = 200, xrange = [-5,5], yrange = [-5,5], line_type = 6, line_width = 3, title = "Hyperbolic Spiral", polar(10/theta,theta,1,10*%pi) )$ |
parametric(xfun,yfun,par,parmin,parmax)
:
monta o gráfico da função paramétrica [xfun,yfun]
, com parâmetro par
assumindo valores de parmin
a parmax
.
Esse objeto é afetado pelas seguintes opções gráficas: nticks
,
line_width
, line_type
, key
, point_type
,
function_style
e point_type
.
Exemplo:
(%i1) load(draw)$ (%i2) draw2d(explicit(exp(x),x,-1,3), line_type = 3, key = "This is the parametric one!!", parametric(2*cos(rrr),rrr^2,rrr,0,2*%pi))$ |
Veja também as seguintes opções gráficas: xrange
, yrange
,
logx
, logy
, terminal
, grid
, title
,
xlabel
, ylabel
, xtics
, ytics
, xy_file
,
file_name
, pic_width
, pic_height
,
user_preamble
, axis_bottom
, axis_left
, axis_top
,
e axis_right
.
A função gr3d
constrói um objeto descrevendo um fundo gráfico tridimensional. Argumentos são
opções gráficas e objetos gráficos. Esse fundo gráfico é interpretado
seqüêncialmente: opções gráficas afetam aqueles objetos gráficos colocados
imediatamente à sua direita.
Para fazer uso dessa função escreva primeiramente load(draw)
.
Essa é a lista dos objetos gráficos disponíveis para fundos gráficos tridimensionais:
points([[x1,y1,z1], [x2,y2,z2], [x3,y3,z3],...])
ou
points([x1,x2,x3,...], [y1,y2,y3,...], [z1,z2,z3,...])
:
posiciona os pontos [x1,y1,z1]
, [x2,y2,z2]
, [x2,y2,z3]
, ... no gráfico.
Esse objeto é afetado pelas seguintes opções gráficas: point_size
,
point_type
, points_joined
, line_width
, key
e line_type
.
Exemplos:
Uma amostra tridimensional,
(%i1) load(draw)$ (%i2) load (numericalio)$ (%i3) s2 : read_matrix (file_search ("wind.data"))$ (%i4) draw3d(title = "Velocidades diárias de ventos disponíveis", point_size = 2, points(args(submatrix (s2, 4, 5))) )$ |
Duas amostras tridimensionais,
(%i1) load(draw)$ (%i2) load (numericalio)$ (%i3) s2 : read_matrix (file_search ("wind.data"))$ (%i4) draw3d(title = "Velocidades diárias de ventos disponíveis. Dois conjuntos de dados", point_size = 2, key = "Amostras das estações 1, 2 e 3", points(args(submatrix (s2, 4, 5))), point_type = 4, key = "Amostras das estações 1, 4 e 5", points(args(submatrix (s2, 2, 3))) )$ |
label(rótulo,x,y,z)
:
escreve rótulo
no ponto [x,y,z]
.
Esse objeto é afetado pelas seguintes opções gráficas: label_alignment
,
label_orientation
e label_color
.
Exemplo:
(%i1) load(draw)$ (%i2) draw3d(explicit(exp(sin(x)+cos(x^2)),x,-3,3,y,-3,3), label_color = 6, label("UP",-2,0,3), label_color = 3, label("DOWN",2,0,-3) )$ |
explicit(fcn,var1,minval1,maxval1,var2,minval2,maxval2)
:
monta o gráfico da função explícita fcn
, com a variável var1
assumindo valores
de minval1
a maxval1
e variável var2
assumindo valores
de minval2
a maxval2
.
Esse objeto é afetado pelas seguintes opções gráficas: xu_grid
,
yv_grid
, line_type
e key
.
Exemplo:
(%i1) load(draw)$ (%i2) draw3d(key = "Gauss", line_type = 2, explicit(20*exp(-x^2-y^2)-10,x,-3,3,y,-3,3), yv_grid = 10, line_type = 5, key="Plane", explicit(x+y,x,-5,5,y,-5,5), surface_hide = true)$ |
parametric(xfun,yfun,zfun,par,parmin,parmax)
:
monta o gráfico da curva paramétrica [xfun,yfun,zfun]
, com parâmetro par
assumindo valores de parmin
a parmax
.
Esse objeto é afetado pelas seguintes opções gráficas: nticks
,
line_width
, line_type
e key
.
Exemplo:
(%i1) load(draw)$ (%i2) draw3d(explicit(exp(sin(x)+cos(x^2)),x,-3,3,y,-3,3), line_type = 3, parametric(cos(5*u)^2,sin(7*u),u-2,u,0,2), line_type = 6, line_width = 2, parametric(t^2,sin(t),2+t,t,0,2), surface_hide = true, title = "Surface & curves" )$ |
parametric_surface(xfun,yfun,zfun,par1,par1min,par1max,par2,par2min,par2max)
:
monta o gráfico da superfície paramétrica [xfun,yfun,zfun]
, com parâmetro par1
assumindo valores de par1min
a par1max
e o parâmetro par2
assumindo valores de par2min
a par2max
.
Esse objeto é afetado pelas seguintes opções gráficas: nticks
,
line_width
, line_type
, e key
.
Exemplo:
(%i1) load(draw)$ (%i2) draw3d(title = "Concha do mar", xu_grid = 100, yv_grid = 25, rot_vertical = 100, rot_horizontal = 20, surface_hide = true, parametric_surface(0.5*u*cos(u)*(cos(v)+1), 0.5*u*sin(u)*(cos(v)+1), u*sin(v) - ((u+3)/8*%pi)^2 - 20, u, 0, 13*%pi, v, -%pi, %pi) )$ |
Veja também as seguintes opções gráficas: xrange
, yrange
,
zrange
, logx
, logy
, logz
, terminal
,
grid
, title
, xlabel
, ylabel
, zlabel
,
xtics
, ytics
, ztics
, xy_file
,
user_preamble
, axis_bottom
, axis_left
,
axis_top
, file_name
, pic_width
, pic_height
,
axis_right
, rot_vertical
, rot_horizontal
,
axis_3d
, xu_grid
, yv_grid
, surface_hide
,
contour
, e contour_levels
.
Monta o fundo de uma série de gráficos; seus argumentos são objetos gr2d
e
gr3d
, juntamente com algumas opções. Por padrão, o fundos gráficos são colocados juntos
em uma coluna.
A função draw
aceita duas opções possíveis: terminal
e columns
.
As funções draw2d
e draw3d
são atalhos para serem usados
quando somente um fundo gráfico é requerido, em duas ou três dimensões, respectivamente.
Para fazer uso dessa função escreva primeiramente load(draw)
.
Exemplo:
(%i1) load(draw)$ (%i2) scene1: gr2d(title="Ellipse", nticks=30, parametric(2*cos(t),5*sin(t),t,0,2*%pi))$ (%i3) scene2: gr2d(title="Triangle", polygon([4,5,7],[6,4,2]))$ (%i4) draw(scene1, scene2, columns = 2)$ |
Essa função é um atalho para
draw2d(gr2d(opções, ..., objeto gráfico, ...))
.
Pode ser usada para montar gráfico de um único fundo bidimensional.
Para fazer uso dessa função escreva primeiramente load(draw)
.
Essa função é um atalho para
draw3d(gr3d(opções, ..., objeto gráfico, ...))
.
Pode ser usada para montar o fundo gráfico único tridmensional.
Para fazer uso dessa função escreva primeiramente load(draw)
.
Valor padrão: true
Quando draw_pipes
for true
, Maxima comunica-se com Gnuplot
diretamente (via pipes). Se draw_pipes
for false
, Maxima comunica-se
com Gnuplot via arquivos. Essa opção não está disponível para usuários windows.
[ << ] | [ >> ] | [Top] | [Contents] | [Índice] | [ ? ] |
This document was generated by Robert Dodier on Maio, 2 2007 using texi2html 1.76.